 	******************************
 	* I MIGHT AS WELL BE ON MARS *
 	* -------------------------- *
 	*  (C) THE MISFITS SOFTWARE  *
 	*          06/04/92          *
 	*  CODED FOR MEGA LEIF DEMO  *
 	*        FROM ELECTRA        *
 	*  ------------------------  *
 	*  CODE.............EPSILON  *
 	*  BALL GFX...........VIXIT  *
 	*  SOUNDCHIP...........EPIC  *
 	*  TEXT...............VIXIT  *
 	*  SOUNDTRACK.........AMIGA  *
 	*  REPLAYTRACK..........???  *
 	*  PICTURE....STARFIELD H.D  *
 	******************************
	include a:\big_star.\util.lib
	
present	equ 1	0=off/1=on

* pour runner la demo sous devpac mettre present a zero
* c'est plus rapide pour assembler et tester et en plus
* ca plante au retour a devpac quand y a le sountrack !

* FOR RUN THE DEMO WITH DEVPAC WITHOUT THE PRESENTATION,PUT PRESENT
* TO 0 BECAUSE IF YOU ASSEMBLE WITH THE PRESENTATION : NO DEVPAC RETURN
* TRY TO DEBUG IT !!! GOOD LUCK ELECTRA !!!
	opt o+,w-,d-
	
	supexec main
	pterm
	
main	jsr init
	ifne present
	jsr presentation
	endc
	jsr clr_bss
	
	jsr init_var
	jsr init_ad
	jsr init_ad2
	jsr add_lettre
	jsr clr_screen
	jsr init2
loop	jsr wait_vbl
	jsr swap_screen

	jsr music+4
	jsr eff_curseur
	jsr aff_txt
	jsr aff_curseur

	cmp.b #$39,$fffffc02.w
	bne.s loop
exit	jsr restore
	rts
	
clr_bss	lea bss,a0
	lea ecran,a1
clr_bss_s1	clr.l (a0)+
	cmp.l a1,a0
	blt.s clr_bss_s1
	rts

init_var	move.l #ecran,d0
	clr.b d0
	move.l d0,screen1
	add.l #64512,d0
	move.l d0,screen2
	move.l #old_stars1,ad_back1
	move.l #old_stars2,ad_back2
	move.l #stars,pt_stars
	move.l #message2,pt_msg
	move.w #20,crd_x
	move.l #166,crd_y
	move.l #166,crd_y2
	move.b #1,wait_txt
	move.b #1,wait_txt2
	move.b #1,flag_curs
	rts
	
init	move.w #$2700,sr
	getphys2 oldphys
	getrez2 oldrez
	savepal oldpal
	mouseoff
	soundoff
	move.b $fffffa07.w,old07
	move.b $fffffa09.w,old09
	move.b $fffffa13.w,old13
	move.b $fffffa15.w,old15
	move.b $fffffa17.w,old17
	move.b $fffffa19.w,old19
	move.b $fffffa1b.w,old1b
	move.b $fffffa1d.w,old1d
	move.b $fffffa1f.w,old1f
	move.l $68.w,old_hbl
	move.l $70.w,old_vbl
	move.l $134.w,old_134
	rts
	
init2	clr.b $fffffa07.w
	clr.b $fffffa09.w
	clr.b $fffffa13.w
	move.l #v68,$68.w
	move.l #vbl2,$70.w
	or.b #1,$fffffa07.w
	bset #5,$fffffa09.w
	or.b #1,$fffffa13.w
	bclr #5,$fffffa15.w
	moveq #1,d0
	jsr music
	move.w #$2100,sr
	jsr wait_vbl
	setscreen2 #0,screen1
	loadpal palette
	move.l #vbl,$70.w
	rts
	
restore	move.l #vbl2,$70.w
	jsr wait_vbl
	move.w #$2700,sr
	soundoff
	setscreen2 oldrez,oldphys
	move.b old07,$fffffa07.w
	move.b old09,$fffffa09.w
	move.b old13,$fffffa13.w
	move.b old15,$fffffa15.w
	move.b old17,$fffffa17.w
	move.b old19,$fffffa19.w
	move.b old1b,$fffffa1b.w
	move.b old1d,$fffffa1d.w
	move.b old1f,$fffffa1f.w
	move.l old_hbl,$68.w
	move.l old_vbl,$70.w
	move.l old_134,$134.w
	loadpal oldpal
	mouseon
	rts
	
swap_screen	movem.l screen1,d0-d3
	exg.l d0,d1
	exg.l d2,d3
	movem.l d0-d3,screen1
	lsr.w #8,d1
	move.l d1,$ffff8200.w
	rts

clr_screen	movem.l screen1,a0-a1
	move.w #64512/4-1,d0
clr_scrs1	clr.l (a0)+
	clr.l (a1)+
	dbra d0,clr_scrs1
	rts
	
wait_vbl	sf.b pt_vbl
wait_vbls1	tst.b pt_vbl
	beq.s wait_vbls1
	rts
	
vbl2	st.b pt_vbl
	rte
	
vbl	st.b pt_vbl
	loadpal palette
	cmp.l #end_stars,pt_stars
	bne.s vbls1
	move.l #stars,pt_stars
vbls1	move.b #32,flag68_1
	move.l #v68,$68.w
	and.w #$f1ff,(sp)
	rte

v68	subq.b #1,flag68_1
	bmi.s v68s1
	rte
v68s1	move.l #v68s3,$68.w
	bclr #6,$fffffa15.w
v68s2	stop #$2100
	bra.s v68s2

v68s3	move.w #$2700,sr
	addq.w #6,sp
	movem.l d0-a6,-(sp)
	moveq #0,d0
	lea $ffff8209.w,a0
	move.w #$60,d2
	move.w #10,d1
	nnop 53
	move.b #0,$ffff820a.w
	moveq #2,d3
v68s4	nop
	dbra d3,v68s4
	move.b #2,$ffff820a.w
	nnop 8
v68s5	move.b (a0),d0
	cmp.b #$40,d0
	bgt.s v68s6
	dbra d1,v68s5
v68s6	sub.w d0,d2
	lsl.w d2,d0
	moveq #0,d0
	moveq #0,d1
	moveq #0,d2
	moveq #0,d3
	move.l screen2,d7
	add.l #160,d7
	lea $ffff8260.w,a1
	lea $ffff820a.w,a0
	move.l ad_back2,a2
	move.l pt_stars,a3
	move.l a2,a4
	lea ad_balls,a5

	nnop 23

	incbin a:\big_star\eff_spr.ful	37 lines

	rept 38
	move.w a1,(a1)
	nop
	move.b d0,(a1)
	move.w (a3)+,d1
	move.l d7,a2
	add.l d1,a2
	move.l a2,(a4)+
	move.b (a3)+,d2
	move.l (a5,d2.w),a6
	move.b (a3)+,d2
	move.l (a6,d2.w),a6
	dcb.w 67,$4e71
	move.b d0,(a0)
	move.w a1,(a0)
	dcb.w 13,$4e71
	move.w a1,(a1)
	nop
	move.b d0,(a1)
	dcb.w 8,$4e71
	jsr (a6)
	endr

	move.w a1,(a1)
	nop
	move.b d0,(a1)
	nnop 89
	move.b d0,(a0)
	move.w a1,(a0)
	nnop 13
	move.w a1,(a1)
	nop
	move.b d0,(a1)
	nnop 9

	move.b d0,(a0)
	move.w a1,(a1)
	nop
	nop
	move.b d0,(a1)
	move.w a1,(a0)
	nnop 87
	move.b d0,(a0)
	move.w a1,(a0)
	nnop 13
	move.w a1,(a1)
	nop
	move.b d0,(a1)
	nnop 12

	rept 3
	move.w a1,(a1)
	nop
	move.b d0,(a1)
	move.w (a3)+,d1
	move.l d7,a2
	add.l d1,a2
	move.l a2,(a4)+
	move.b (a3)+,d2
	move.l (a5,d2.w),a6
	move.b (a3)+,d2
	move.l (a6,d2.w),a6
	dcb.w 67,$4e71
	move.b d0,(a0)
	move.w a1,(a0)
	dcb.w 13,$4e71
	move.w a1,(a1)
	nop
	move.b d0,(a1)
	dcb.w 8,$4e71
	jsr (a6)
	endr

	rept 28
	move.w a1,(a1)
	nop
	move.b d0,(a1)
	nnop 89
	move.b d0,(a0)
	move.w a1,(a0)
	nnop 13
	move.w a1,(a1)
	nop
	move.b d0,(a1)
	nnop 12
	endr

	move.l a3,pt_stars
	move.w #$700,$ffff8240.w
	move.l #v68_end,$68.w
	bset #6,$fffffa15.w
	movem.l (sp)+,d0-a6
	or.w #$300,(a7)
v68_end	rte

eff_txt	movem.l screen1,a0-a1
	add.l crd_y2,a0
	add.l crd_y2,a1
	moveq #0,d0
	v_init offset,0
	rept 28
	move.w d0,offset(a0)
	move.w d0,offset(a1)
	v_inc offset,8
	endr
	add.l #230,crd_y2
	cmp.l #(273*230)+166,crd_y2
	blt.s eff_txtend
	move.w #20,crd_x
	move.l #166,crd_y
	move.l #166,crd_y2
	sf.b flag_msg
	move.b #1,wait_txt
	move.b #1,wait_txt2
eff_txtend	rts

aff_txt	tst.b flag_msg
	bne eff_txt
	subq.b #1,wait_txt
	bne aff_txtend
	move.b wait_txt2,wait_txt
	movem.l screen1,a0-a1
	move.l crd_y,d0
	add.l d0,a0
	add.l d0,a1
	move.l pt_msg,a2
	lea fonte,a3
	moveq #0,d0
	move.b (a2)+,d0
	cmp.b #-1,d0
	bne.s aff_txts1
	st.b flag_msg
	lea message,a2
	bra aff_txtend2
aff_txts1	cmp.b #0,d0
	bne.s aff_txts2
	move.w #20,crd_x
	add.l #8*230,crd_y
	bra aff_txtend2
aff_txts2	cmp.b #1,d0
	bne.s aff_txts3
	move.b (a2),wait_txt
	move.b (a2)+,wait_txt2
	bra aff_txtend2
aff_txts3	cmp.b #2,d0
	bne.s aff_txts4
	eor.b #%11110000,flag_soul
	bra aff_txtend2
aff_txts4	cmp.b #3,d0
	bne.s aff_txts5
	eor.b #%11110000,flag_eor
	bra aff_txtend2
aff_txts5	cmp.b #4,d0
	bne.s aff_txts6
	eor.b #1,flag_curs
	bra aff_txtend2
aff_txts6	cmp.b #5,d0
	bne.s aff_txts7
	subq.w #4,crd_x
	bra aff_txtend2
aff_txts7	cmp.b #6,d0
	bne.s aff_txts8
	add.l #8*230,crd_y
	bra aff_txtend2
aff_txts8	cmp.b #7,d0
	bne.s aff_txts9
	sub.l #8*230,crd_y
	bra aff_txtend2
aff_txts9	cmp.b #8,d0
	bne.s aff_txts10
	st.b flag_msg
	bra aff_txtend2
aff_txts10
aff_txts99	sub.b #" ",d0
	mulu #5,d0
	lea (a3,d0.w),a3
	move.w crd_x,d0
	move.w d0,d1
	and.w #$fff0,d1
	lsr.w #1,d1
	add.w d1,a0
	add.w d1,a1
	and.w #$000f,d0
	moveq #0,d1
	moveq #0,d2
	moveq #0,d3
	moveq #0,d4
	moveq #0,d5
	moveq #0,d6
	move.b (a3)+,d1
	move.b (a3)+,d2
	move.b (a3)+,d3
	move.b (a3)+,d4
	move.b (a3)+,d5
	move.b flag_soul,d6
	move.b flag_eor,d7
	eor.b d7,d1
	eor.b d7,d2
	eor.b d7,d3
	eor.b d7,d4
	eor.b d7,d5
	ror.l d0,d1
	ror.l d0,d2
	ror.l d0,d3
	ror.l d0,d4
	ror.l d0,d5
	ror.l d0,d6
	or.w d1,(a0)
	or.w d1,(a1)
	or.w d2,1*230(a0)
	or.w d2,1*230(a1)
	or.w d3,2*230(a0)
	or.w d3,2*230(a1)
	or.w d4,3*230(a0)
	or.w d4,3*230(a1)
	or.w d5,4*230(a0)
	or.w d5,4*230(a1)
	or.w d6,6*230(a0)
	or.w d6,6*230(a1)
	swap d1
	swap d2
	swap d3
	swap d4
	swap d5
	swap d6
	or.w d1,8(a0)
	or.w d1,8(a1)
	or.w d2,8+1*230(a0)
	or.w d2,8+1*230(a1)
	or.w d3,8+2*230(a0)
	or.w d3,8+2*230(a1)
	or.w d4,8+3*230(a0)
	or.w d4,8+3*230(a1)
	or.w d5,8+4*230(a0)
	or.w d5,8+4*230(a1)
	or.w d6,8+6*230(a0)
	or.w d6,8+6*230(a1)
	addq.w #4,crd_x
aff_txtend2	move.l a2,pt_msg
aff_txtend	rts

eff_curseur	tst.b flag_msg
	bne.s aff_txtend
	movem.l screen1,a0-a1
	add.l ad_old_curs,a0
	add.l ad_old_curs,a1
	move.l img_old_curs,d0
	and.w d0,0+(0*230)(a0)
	and.w d0,0+(0*230)(a1)
	and.w d0,0+(1*230)(a0)
	and.w d0,0+(1*230)(a1)
	and.w d0,0+(2*230)(a0)
	and.w d0,0+(2*230)(a1)
	and.w d0,0+(3*230)(a0)
	and.w d0,0+(3*230)(a1)
	and.w d0,0+(4*230)(a0)
	and.w d0,0+(4*230)(a1)
	and.w d0,0+(5*230)(a0)
	and.w d0,0+(5*230)(a1)
	and.w d0,0+(6*230)(a0)
	and.w d0,0+(6*230)(a1)
	swap d0
	and.w d0,8+(0*230)(a0)
	and.w d0,8+(0*230)(a1)
	and.w d0,8+(1*230)(a0)
	and.w d0,8+(1*230)(a1)
	and.w d0,8+(2*230)(a0)
	and.w d0,8+(2*230)(a1)
	and.w d0,8+(3*230)(a0)
	and.w d0,8+(3*230)(a1)
	and.w d0,8+(4*230)(a0)
	and.w d0,8+(4*230)(a1)
	and.w d0,8+(5*230)(a0)
	and.w d0,8+(5*230)(a1)
	and.w d0,8+(6*230)(a0)
	and.w d0,8+(6*230)(a1)
	rts

aff_curseur	tst.b flag_msg
	bne.s aff_curseurs2
	tst.b flag_curs
	bne.s aff_curseurs1
aff_curseurs2	rts
aff_curseurs1	movem.l screen1,a0-a1
	move.l crd_y,d2
	move.w crd_x,d0
	move.w d0,d1
	and.l #$fff0,d1
	lsr.w #1,d1
	add.l d1,d2
	move.l d2,ad_old_curs
	add.l d2,a0
	add.l d2,a1
	and.w #$000f,d0
	move.l #%11110000,d1
	ror.l d0,d1
	move.l d1,d2
	eor.l #-1,d2
	move.l d2,img_old_curs
	or.w d1,(a0)
	or.w d1,(a1)
	or.w d1,1*230(a0)
	or.w d1,1*230(a1)
	or.w d1,2*230(a0)
	or.w d1,2*230(a1)
	or.w d1,3*230(a0)
	or.w d1,3*230(a1)
	or.w d1,4*230(a0)
	or.w d1,4*230(a1)
	or.w d1,5*230(a0)
	or.w d1,5*230(a1)
	or.w d1,6*230(a0)
	or.w d1,6*230(a1)
	swap d1
	or.w d1,8(a0)
	or.w d1,8(a1)
	or.w d1,8+1*230(a0)
	or.w d1,8+1*230(a1)
	or.w d1,8+2*230(a0)
	or.w d1,8+2*230(a1)
	or.w d1,8+3*230(a0)
	or.w d1,8+3*230(a1)
	or.w d1,8+4*230(a0)
	or.w d1,8+4*230(a1)
	or.w d1,8+5*230(a0)
	or.w d1,8+5*230(a1)
	or.w d1,8+6*230(a0)
	or.w d1,8+6*230(a1)
	rts

init_ad	lea ball_1,a0
	jsr init_ad1s1
	lea ball_2,a0
	jsr init_ad1s1
	lea ball_3,a0
	jsr init_ad1s1
	lea ball_4,a0
init_ad1s1	moveq #15,d0
	move.l a0,d1
init_ad1s2	add.l d1,(a0)+
	dbra d0,init_ad1s2
	rts

init_ad2	lea old_stars1,a0
	lea old_stars2,a1
	moveq #40,d0
init_ad2s1	move.l screen1,(a0)+
	move.l screen2,(a1)+
	dbra d0,init_ad2s1
	rts

add_lettre	lea fonte,a1
	lea ("+"-" ")*5(a1),a0	lettre "+"
	move.b #%00000000,(a0)+
	move.b #%01000000,(a0)+
	move.b #%11100000,(a0)+
	move.b #%01000000,(a0)+
	move.b #%00000000,(a0)+
	lea ("#"-" ")*5(a1),a0	lettre "#"
	move.b #%11100000,(a0)+
	move.b #%11100000,(a0)+
	move.b #%11100000,(a0)+
	move.b #%11100000,(a0)+
	move.b #%11100000,(a0)+
	rts

	ifne present
presentation	loadpal null
	move.l #ecran2+32256,d0
	clr.b d0
	move.l d0,a3
	move.l d0,a0
	move.w #32000/4-1,d0
presents1	clr.l (a0)+
	dbra d0,presents1
	move.l #vbl2,$70.w
	move.w #$2300,sr
	jsr wait_vbl
	setscreen2 #0,a3
	jsr decomp_pic
	lea pic+2,a0
	jsr fade_out2
	clr.b $fffffa09.w
	lea mod,a0
	jsr replay
presents2	jsr wait_vbl
	jsr replay+4
	cmp.b #$b9,$fffffc02.w
	bne.s presents2
	jsr replay+8
	jsr fade_in
	clr.b $fffffa09.w
	move.w #$2700,sr
	soundoff
	rts

decomp_pic	lea pic+34,a5
dec10	move.l #$c7,d4
	move.l #6,a0
	moveq #4,d6
	moveq #$28,d7
dec9	clr.b d1
	move.l a3,a4
dec8	move.l a4,-(sp)
	clr.b d3
dec7	move.b (a5)+,d0
	tst.b d0
	bmi.s dec1
	addq.b #1,d0
dec3	move.b (a5)+,(a4)+
	addq.b #1,d3
	move.l a4,d5
	btst #0,d5
	bne.s dec2
	add.l a0,a4
dec2	subq.b #1,d0
	bne.s dec3
	bra.s dec4
dec1	neg.b d0
	addq.b #1,d0
	move.b (a5)+,d2
dec6	move.b d2,(a4)+
	addq.b #1,d3
	move.l a4,d5
	btst #0,d5
	bne.s dec5
	add.l a0,a4
dec5	subq.b #1,d0
	bne.s dec6
dec4	cmp.b d7,d3
	BNE.S DEC7
	move.l (sp)+,a4
	addq.l #2,a4
	addq.b #1,d1
	cmp.b d6,d1
	bne.s dec8
	add.l #$a0,a3
	dbra d4,dec9
	rts
;
; fondu de la palette vers le noir.
;
fade_in	moveq #7,d3
fadeins1	jsr wait_vbl
	jsr wait_vbl
	jsr wait_vbl
	jsr wait_vbl
	lea $ffff8240,a0
	moveq #15,d4
fadeins2	move.w (a0),d0
	move.w d0,d1
	move.w d1,d2
	lsr.w #8,d0
	and.w #7,d0
	lsr.w #4,d1
	and.w #7,d1
	and.w #7,d2
	subq.w #1,d0
	bpl.s fadeins3
	moveq #0,d0
fadeins3	subq.w #1,d1
	bpl.s fadeins4
	moveq #0,d1
fadeins4	subq.w #1,d2
	bpl.s fadeins5
	moveq #0,d2
fadeins5	lsl.w #8,d0
	lsl.w #4,d1
	or.w d1,d2
	or.w d2,d0
	move.w d0,(a0)+
	dbra d4,fadeins2
	dbra d3,fadeins1
	rts

tmp_pal	ds.l 1

;
; Fondu du noir vers une palette A0
;
fade_out2	move.l a0,tmp_pal
	moveq #7,d3
fdout2s1	jsr wait_vbl
	jsr wait_vbl
	jsr wait_vbl
	jsr wait_vbl
	move.l tmp_pal,a0
	lea $ffff8240,a1
	moveq #15,d4
fdout2s2	move.w (a0)+,d0
	move.w d0,d1
	move.w d0,d2
	lsr.w #8,d0
	lsr.w #4,d1
	and.w #7,d0
	and.w #7,d1
	and.w #7,d2
	sub.w d3,d0
	bpl.s fdout2s3
	moveq #0,d0
fdout2s3	sub.w d3,d1
	bpl.s fdout2s4
	moveq #0,d1
fdout2s4	sub.w d3,d2
	bpl.s fdout2s5
	moveq #0,d2
fdout2s5	lsl.w #8,d0
	lsl.w #4,d1
	or.w d2,d1
	or.w d1,d0
	move.w d0,(a1)+
	dbra d4,fdout2s2
	dbra d3,fdout2s1
	rts
	endc

	section data

music	incbin a:\big_star\epic.zik

fonte	incbin a:\big_star\font_3x5.fnt
	even

palette	incbin a:\big_star\balls.pal

ball_1	incbin a:\big_star\ball_1.ful
ball_2	incbin a:\big_star\ball_2.ful
ball_3	incbin a:\big_star\ball_3.ful
ball_4	incbin a:\big_star\ball_4.ful

stars	incbin a:\big_star\stars_2.xyz
end_stars	equ *

ad_balls	dc.l ball_1,ball_2,ball_3,ball_4

* code only for text

*Les codes pour le textes sont :
*-1 = Fin du texte
* 0 = Retour a la ligne
* 1 = Vitesse du texte (+1 octet) (minimum a 1)
*     (Permet de faire des wait dans le texte.)
* 2 = Caracteres soulignes (on/off)
* 3 = Caracteres en inversion video (on/off)
*     (Attention le trait de soulignement n'est pas inverse !)
* 4 = Curseur (on/off)
* 5 = Backspace
* 6 = Curseur vers le bas
* 7 = Curseur vers le haut
*     (Attention lors du deplacement du curseur le chars qui
*      se trouve a la nouvelle position du curseur est efface !
*      Le programme ne test pas non plus les sortie d'ecran !!!
*      Alors fais tres attention avec ces commandes !)
* 8 = Fin de la page

* Des le debut de la demo :
* - La vitesse est fixee a 1
* - Le curseur est ON
* - Le soulignement est OFF
* - L'inversion video est OFF

*	      000000000111111111122222222223333333333444444444455555555556666666666777777777788888888889999999
*	      123456789012345678901234567890123456789012345678901234567890123456789012345678901234567890123456
message2	dc.b 4,1,200,1,2,4
message	dc.b 1,2
	dc.b "             YO FOLKS ! THIS HIS THE NEW DEMO OF THE MISFITS SOFTWARE (TMS) CALLED :",0,0
	DC.B "                                  ",2,"I MIGHT AS WELL BE ON MARS",2,0,0
	DC.B "                         CREDITS FOR THIS SCREEN :  - CODE  : EPSILON"
	DC.B 6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"- GFX   :   VIXIT"
	DC.B 6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"- MUSIC :    EPIC"
	DC.B 7,7,5,5,5,5,5,5,5,2,"EPSILON"
	DC.B 6,5,5,5,5,5,"VIXIT"
	DC.B 6,5,5,5,5,"EPIC",2,0,0,0,1,50,1,2
	DC.B "THAT'S WONDERFULL !!!!",1,150,1,2,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5
	DC.B "OK ! YES I KNOW !! YOU CAN SAY THAT THIS SCREEN HAVE A LOOK LIKE MANTA FORCE",5,5,5,5,5,5,5,5,5,5,5,2,"DELTA FORCE",2," IN THE ",2,"PUNISH YOUR",0
	DC.B "MACHINE",2," (THE BEST PART OF THE CREATION) !,BUT HERE ! IT'S NOT A LAME RIPPING BUT A NEW VERSION ",0  
	DC.B "CODED BY ",2,"THE MEGAMINIMIGHTY",2," MISFITS SOFTWARE !AND HERE WE STICK ",2,"3264",2," CHARACTERS IN LOW REZ BUT WE",0
	DC.B "CAN STICK ",2,"5040",2," CHARS WITHOUT UNDERLINE BUT IT'S UNREADABLE ! AND WE STICK ",2,"56545 BALLS",5,5,5,5,5,5,5,5,5,5,5,"41 BALLS",2," IN 3D STAR-",0
	DC.B "FIELD AND ALL IN FULLSCREEN OF COURSE !!!!",0,0
	DC.B "WELL ! WHAT CAN I SAY ??? ",0,0
	DC.B "           HO ! YES I CAN TELL YOU THE NEW LIST UNCHANGED OF THE MISFITS SOFTWARE ",0
	DC.B "",0
	DC.B "                                   ",2,"THE MEMBERS OF TMS ARE :",2,0,0
	DC.B "                                    ",3,"- EPSILON   :    CODER"
	DC.B 6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"- VIXIT     :   GFXMAN"
	DC.B 6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"- EPIC      : MUSICIAN"
	DC.B 6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"- STARFIELD :  CODER ?"
	DC.B 6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"- CORPO     :     ????",3,0,0
	DC.B "                  HO ! I HAVE FORGET TO PRESENT ME  !!!!",0
	DC.B "YES ! AGAIN ! YOU FIND !!! NO LUCK !!! HERE IS AGAIN : ",0
	DC.B "                    ",3,"THE GFXMAN THE MOST BLOODY IDIOT OF THE ST SCENE !",0
	DC.B 3,"                                             VIXIT ",0
	DC.B 1,250,1,250,1,1,"              5...",1,50,1,1,"4...",1,50,1,1,"3...",1,50,1,1,"2...",1,50,1,1,"1...",1,50,1,1,"0..."
	DC.B "AUTODESTRUCTION...",8,1,2
	DC.B "OK GUYS ! I'M BACK HERE FOR TELL YOU SOME REAL GREETINGS TO ALL OUR FRIEND:",0,0
	DC.B 3,"FRENCH GREETINGS :",3,0,0
	DC.B " ARTIS MAGIA ",6," MEGABUSTERS ",7," ",2,"VMAX",6,2," ",2,"HYSTERIA",7,2," ",2,"OVERLANDERS",6,2," LEGACY ",7,"ST CONNEXION",6," ",2,"MISFITS",7,2," ",2,"TSB",6,0
	DC.B 2,"THUNDERBIRDS",6," ",2,"PRISM",7,2," NEW SYSTEM ",6," FULL METAL COMPUTER CONNEXION ",7," COUSCOUS CREW ",6," ULTIMATE ",7," ",2,"TSI",2,6,0
	DC.B " BUSHWACKERS ",6," MJJ PROD ",7,2,"HYSTANDERS",6,2," NAOS ",7," UNDEAD ",6," ",2,"DNT CREW",7,2," ",2,"EXPLORER",6,2," ",2,"FUZION",2,7," ",2,"NEXT",2,6,0
	DC.B 3,"WORLD GREETINGS :",3,0,0
	DC.B 2,"XENEX DEMOZONE 68000",2,6," ALIEN CRACKING FORMATION ",7," SILVERS BULLET FORCE ",6," ",2,"EXCEPTIONS",7,2," ",2,"DELTA FORCE",6,2,0
	DC.B " BLACK MONOLYTH TEAM ",6," THE CODERS ",7," NEWLINE ",6, " TNT CREW ",7," LEVEL 16 ",6," CAREBEARS ",7," OMEGA ",6," SYNC ",7," GHOST ",6,0 
	DC.B " SEWER SOFTWARE ",6," AND OF COURSE : ",0,1,1
	DC.B "###############################################################################################",0
	DC.B "#                                                                                             #",0
	DC.B "#              ###### ##      ######  ###   ###### #####   ####                               #",0                            
	DC.B "#              ##     ##      ##     ##  ##   ##   ##  ## ##  ##                              #",0      
	DC.B "#              ####   ##      ####   ##       ##   #####  ######                              #",0      
	DC.B "#              ##     ##      ##     ##  ##   ##   ## ##  ##  ##                              #",0      
	DC.B "#              ###### ####### ######  ###     ##   ##  ## ##  ##                              #",0                            
	DC.B "#                                                                                             #",0
	DC.B "###############################################################################################",0,1,2
	DC.B " FOR THEIR INVITATIONS AND CONTRIBUTION TO THE MEGA LEIF CONVENTION RELEASED ON 16TH APRIL AT ",0
	DC.B " THE 20TH APRIL 1992 AT ",2,"FYRISSKOLAN",2," IN ",2,"UPPSALA (SWEDEN)...",2,0
	DC.B "BUT SORRY FOR UNPRESENCE OF TMS BECAUSE WE ARE VERY VERY IN THE SHIT WITH THE MONEY BUT IF YOU ",0
	DC.B "ORGANIZED AN OTHER CODING CONFERENCE ! PERHAPS WE GO IT !!!  ",0
	DC.B 1,250,1,250,1,1,"5...",1,50,1,1,"4...",1,50,1,1,"3...",1,50,1,1,"2...",1,50,1,1,"1...",1,50,1,1,"0..."
	DC.B "NO PRAYER FOR THIS SCREEN...",8,1,2
	DC.B 6,6,6," I M VERY HAPPY TO BE WITH YOU HERE BUT I DON'T KNOW WHAT CAN I SAY ",6,6,6,6,6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,7,7,5,5,5,5,6,6,6,6,5,5,5,5,5,5,5,5,5,5,5,5,5,6,7,"                       ",5,5,5,5,"     ",5,5,5,5,"    ",5,5,5,0
	DC.B "    SILLY !! NO ?? ",5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"OK NOW I WANT SAY SOME WORDS !!! :",0	
	DC.B "    FIRST OF ALL !!! WHAT DO YOU THINKS ABOUT THIS SCREEN ??? ",0
	DC.B " YES ! I KNOW YOUR REMARKS !,YOU CAN SAY THAT THIS SCREEN IS GOOD,THE TUNE WAS ALSO GOOD,",0
	DC.B " THE GFX ?,GOOD TOO ! BUT YOU CAN REMARK THAT A LOUSIEST PIECE OF SHIT IS BEEN PRESENT !!! ",0
	DC.B " YES !! THERE'S A BAD SYNCHRONISATION IN THE DATA FOR THE 3D STARFIELD,BECAUSE ALL MEMBERS",0
	DC.B " OF TMS ARE REALLY BAD FOR 3D MATHEMATICAL CALCULS (SORRY !! ALSO FOR THE ENGLISH LANGUAGE) ",0,6,6
	DC.B " HO ! BY THE WAY !!! , HAVE YOU OUR SOUND DEMO CALLED ",6,6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,3,"THE ANOTHER ILLUSION DEMO ??",0,3
	DC.B " NO ? HO !! YOU'RE SO WRONG TAKE A PEN'S AND A PAPER AND PREPARE TO WRITE OUR ADRESS :",0,6
	DC.B "                      YOU CAN CONTACT THE MISFITS SOFTWARE AT 2 ADRESS : ",0
	DC.B "              ",3,"VIXIT :",6,3,5,5,5,5,5,5,5,"VIXIT CHEZ SANCHEZ MORENO",6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"8 RUE DE PROVENCE",6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"38130  ECHIROLLES",6,5,5,5,5,5,5,5,5,5,5
	DC.B 5,5,5,5,5,5,5,"ISERE  FRANCE"
	DC.B "     ",7,7,7,7,"          ",3,"STARFIELD :",6,3,5,5,5,5,5,5,5,5,5,5,5,"PATRICE ANGEL",6,5,5,5,5,5,5,5,5,5,5,5,5,5,"CHEMIN DES MULETS",6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,"07500 GUILHERAND",6,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5,5
	DC.B "ARDECHE  FRANCE",0,1,150,1,2
	DC.B 1,250,1,250,1,1,"5...",1,50,1,1,"4...",1,50,1,1,"3...",1,50,1,1,"2...",1,50,1,1,"1...",1,50,1,1,"0..."
	DC.B "SEEK AND DESTROY...",8,1,2
	DC.B "                 NOW IF YOU LIKE PLUBLICITY,YOU'VE GOT IT !!",0,6,6
	DC.B 2,"THE MISFITS SOFTWARE",2," IS AN ACTIVE CREW WHO'S MAKE A LOT OF GUEST SCREEN WITH ONLY :",0
	DC.B "                 ONE CODER,ONE MUSICIAN,ONE BEGIN CODER AND ONE PAINTER...",0
	DC.B " AND YOU CAN FIND ALL OUR PRODUCTIONS IN ALL MEGADEMO...(IN ORDERS OF SCREEN CODED!)",0
	DC.B 6,6,"      ",3,"DEMO NAME :",3,"                  ",3,"SCREEN NAME:",3,"             ",3,"DEMO FROM:",3,0,1,1
	DC.B 6,"        THE RIPDIS MEGADEMO          WONDERFULL SCROLL          NEXT ",0
	DC.B 6,"        THE DEUS X MACHINA MEGADEMO  RED SECTOR II              ARTIS MAGIA",0
	DC.B 6,"        THE SNORK II MEGADEMO        WIZZ                       FUTUR MIND",0
	DC.B 6,"        THE PHALEON MEGADEMO (???)   CAN'T STOP ROCKIN          NEXT",0
	DC.B 6,"        THE CODING SO FAR MEGADEMO   WAY OF THE SCROLL          MEGABUSTERS",0
	DC.B 6,"        THE MEGAFUN II MEGADEMO      LOST IN UNIVERSE           THE STORM BROTHERS",0
	DC.B 6,"AND NOW THE MEGA LEIF MEGADEMO       I MIGHT AS WELL BE ON MARS ELECTRA ",0,1,2
	DC.B 6,6,6,"      GREAT NO ?? WELL NOW I THINKS IT'S TIME TO QUIT BUT JUST BEFORE WRAPPING ",0
	DC.B " ANOTHER LAST THINGS IN THE NEXT SCREEN....",0,6,6
	DC.B 1,250,1,250,1,1,"5...",1,50,1,1,"4...",1,50,1,1,"3...",1,50,1,1,"2...",1,50,1,1,"1...",1,50,1,1,"0..."
	DC.B "KILL'EM ALL...",8,1,2
	DC.B "     ATTENTION     ATTENTION    ATTENTION    ATTENTION    ATTENTION    ATTENTION    ATTENTION",0
	DC.B 6,6,3," THE MISFITS SOFTWARE ",3," MAKE A MEGADEMO CALLED :",6,6,5,5,5,5,5,5,5,5,5,5,5,5,5,3,"THE TRANSALP MEGADEMO",3,6,5,5,5,5,5,5,5,5,2,"LICENSE TO CODE...",2,6,0
	DC.B " AND WE SEARCHING A LOT OF GUEST SCREENS FOR THIS MEGADEMO !!!",0
	DC.B " IF YOU ARE A GOOD CREW WITH FUN OF DEMO CODE AND IF YOU ARE INTERESTED TO PARTICIPATE TO THIS",0
	DC.B " MEGADEMO.CONTACT US ",2,"NOW",2,",AND START CODING NOW !!!",0
	DC.B " SOME CREW HAVE ALLREADY FINISH TO CODE THEIR SCREENS,THIS CREW  ARE :",0
	DC.B 6,"              PRISM      THUNDERBIRDS      NEW SYSTEM   ",0
	DC.B 6," AND THE OTHERS ARE IN PREPARATION IN THE WORKROOM OF :",0
	DC.B 6,"           OVERLANDERS     MJJ PROD    XENEX DEMOZONE 68000 ",0
	DC.B " THIS MEGADEMO IS ALLREADY COMPOSED OF: ",0
	DC.B "        PRESENTATION RSI................................MISFITS SOFTWARE",0
	DC.B "        GOLDMENU........................................MISFITS SOFTWARE",0
	DC.B "        LOADER SATRIANI.................................MISFITS SOFTWARE",0
	DC.B "        LAMERTEST DISTFULL..............................MISFITS SOFTWARE",0
	DC.B "        GRATEFULL DEAD.............................................PRISM",0
	DC.B "        T.D.W.P.A.W.E.P.....................................THUNDERBIRDS",0
	DC.B "        NEW SYSTEM............................................NEW SYSTEM",0
	DC.B "        AND 3 MISFITS SCREENS.....",0,0                       
	DC.B " SO ! YOU HAVE AGAIN THE TIME TO MAKE A GREAT SCREEN BECAUSE ",3,"EPSILON",3," IS IN THE ARMY NOW !!!...",0,0
	DC.B 1,250,1,250,1,1,"5...",1,50,1,1,"4...",1,50,1,1,"3...",1,50,1,1,"2...",1,50,1,1,"1...",1,50,1,1,"0..."
	DC.B "HASTA LA VISTA...",8,1,2
	DC.B " AND HERE THE LAST THINKS !!!!!",0
	DC.B " YES ! WE WANT DEDICATE THIS SCREEN TO ALL CREW LIVING IN OUR COUNTRY CALLED ISERE !!!!",0,6,6,6
	DC.B " THESE GREATS FRIENDS ARE : ",0,0
	DC.B "            ",3,"OVERLANDERS",3,".....................................TYPHON,SPEEDLIGHT",0,0
	DC.B "            ",3,"HYSTERIA",3,"..................................XRAY,CAPTAIN BUG,MADMAN",0,0
	DC.B "            ",3,"NEXT",3,"..........................................................LAP",0,0
	DC.B "            ",3,"VMAX",3,"......................................................B.V.C.A",0,0
	DC.B "            ",3,"FULL METAL COMPUTER CONNEXION",3,"............KRISTAL,KRYSTAL,KILLER D",0,0
	DC.B "            ",3,"LIGHTNING",3,".................................................STARMAN",0,0
	DC.B "            AND LAST BUT NOT LEAST ALL THE CRAZY CRACKER CREW MEMBERS ON AMIGA ",0,0
	DC.B " OK NOW WE APPROCHING TO THE END OF THIS GREAT SCREEN CODED ESPECIALLY FOR THIS ",3,"ELECTRA",3,0
	DC.B " MEGADEMO.JUST TIME TO SAY THAT WE ARE ALWAYS ON THE ST TO MAKE DEMO BIT BY BIT (HI TEX !)",0
	DC.B " AND PLEASE PRAY AGAIN FOR THE NEXT YEARS TO GO FOR OUR DEAR ATARI ST BECAUSE HIS DEAD IS",0
	DC.B " APPROCHING... THE GAME CRACKING KILL THE ST BIT BY BIT ! IF YOU ARE CRACKERS,I KNOW,",0
	DC.B " YOU CAN'T STOP TO CRACK 10 GAMES TODAY AND NOTHING TOMMOROW,IT'S THE SAME THINKS FOR",0
	DC.B " A BIGGEST SMOKER,BUT TRY TO STOP CRACKING LITTLE BY LITTLE,REMEMBER YOU ALL OLDS OTHERS",0
	DC.B " COMPUTERS : ATARI 800 XL,ORIC ATMOS,SPECTRUM,AMSTRAD (NDLR:REMARK SHIT COMPUTER) AND MANY",0
	DC.B " OTHERS...DON'T KILL THE ST FOR GOING ON AMIGAAAARRRGGHHH ",0
	DC.B "              (WHAT DO YOU THINKS ABOUT THIS,DXT SYNCHRON ???)",0
	DC.B 1,250,1,250,1,1,"5...",1,50,1,1,"4...",1,50,1,1,"3...",1,50,1,1,"2...",1,50,1,1,"1...",1,50,1,1,"0..."
	DC.B "THE FINAL COUNTDOWN ???...",8,1,2
	DC.B " OK HERE'S THE END ",0
	DC.B "   AND FOR THE LAST PART !!! DON'T FORGET AND REMEMBER YOU THIS FOR THE TRANSALP MEGADEMO !!!  ",0,0,1,1
	DC.B "###############################################################################################",0
	DC.B "#                                                                                             #",0
	DC.B "# #####  ####   #### ##### #      ###  #   #          #####  ####         ##### #   #  #####  #",0
	DC.B "# #      #   # #       #   #     #   # ##  #            #   #               #   #   #  #      #",0
	DC.B "# ###    ####   ###    #   #     #   # # # #            #    ###            #   #####  ###    #",0
	DC.B "# #      #         #   #   #     #   # #  ##            #       #           #   #   #  #      #",0
	DC.B "# #####  #     ####  ##### #####  ###  #   #          ##### ####            #   #   #  #####  #",0
	DC.B "#                                                                                             #",0
	DC.B "#                             ####  #####  #### #####    ## ## ##                             #",0
	DC.B "#                             #   # #     #       #      ## ## ##                             #",0
	DC.B "#                             ####  ###    ###    #      ## ## ##                             #",0
	DC.B "#                             #   # #         #   #                                           #",0
	DC.B "#                             ####  ##### ####    #      ## ## ##                             #",0
	DC.B "#                                                                                             #",0
	DC.B "###############################################################################################",0,0,1,2
	DC.B " (ARF ! CA C'EST BIN VRAI !!!)  EPSILON.....15/03/92",0,0
	DC.B "OK ! NOW IT'S TIME TO QUIT MARS FOR RETURN TO OUR OLD GOOD BLUE PLANET WITH ALL HIS UGLY PEOPLE",0
	DC.B " GOODBYE AND SEE YOU SOON IN OTHERS TMS PRODUCTIONS AND CONVENTIONS....",0,0
	DC.B " LET'S HAVE FUN WITH THE OTHERS SCREENS IN THIS MEGA MEGA MEGA LEIF DEMO BYE",0,0
	DC.B "                               ",2,"VIXIT",2,0
	DC.B "                                                        (C) THE MISFITS SOFTWARE 06/04/1992",0,0,0
	DC.B "LET'S WRAP IN 15 SECONDES ..."
	DC.B 1,250,1,250,1,1,"5...",1,50,1,1,"4...",1,50,1,1,"3...",1,50,1,1,"2...",1,50,1,1,"1...",1,50,1,1,"0..."
	DC.B "WARP FROM THALION...",-1

old_vbl	ds.l 1
old_hbl	ds.l 1
old_134	ds.l 1
oldphys	ds.l 1
oldrez	ds.w 1
oldpal	ds.w 16
old07	ds.b 1
old09	ds.b 1
old13	ds.b 1
old15	ds.b 1
old17	ds.b 1
old19	ds.b 1
old1b	ds.b 1
old1d	ds.b 1
old1f	ds.b 1
pt_vbl	ds.b 1

bss	equ *
flag68_1	ds.b 1
flag_msg	ds.b 1

screen1	ds.l 1
screen2	ds.l 1
ad_back1	ds.l 1
ad_back2	ds.l 1

crd_x	ds.w 1
crd_y	ds.l 1
crd_y2	ds.l 1
pt_msg	ds.l 1
ad_old_curs	ds.l 1
img_old_curs	ds.l 1
wait_txt	ds.b 1
wait_txt2	ds.b 1
flag_eor	ds.b 1
flag_curs	ds.b 1
flag_soul	ds.b 1
	ds.b 1

old_stars1	ds.l 41
old_stars2	ds.l 41

pt_stars	ds.l 1

null	ds.l 16

	ifne present
replay	incbin a:\big_star\replay.bin

mod	incbin a:\big_star\vector.mod
	even
	
pic	incbin a:\big_star\present.pc1
	even

	ds.b 256
ecran2	equ *
ecran	equ replay+256
	elseif
	ds.b 256
ecran	equ *
	endc


	end